***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 06, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJQ5448  D  G  S
Rg     G    1t    1
EVgs   2t    3 TABLE { V(1t, S) } 
+((0, 0)
+ (0.5 , 0.5  )
+ (1   , 1.1  )
+ (1.5 , 1.5  )
+ (2   , 2.2  )
+ (2.5 , 2.8  )
+ (3   , 3.4  )
+ (3.5 , 4    )
+ (4   , 4.6  )
+ (4.5 , 5    )
+ (5   , 5.3  )
+ (10  , 7.2  )
+ (20  , 7.2  ))
EVgst 1 2t value = {1e-3*limit(v(2t,3),0,5)*limit((temp-25),-65,125)}
M1      2    1    3    3    DMOS    L=1u   W=1u
.MODEL DMOS NMOS (
+  VTO = 2.02
+   KP = 29.6
+LEVEL = 3
+ TNOM = 25)
Cgs    1t    3    9.782e-10 ic=0
Rd      D    4    2.484e-3 tc=1.543e-2
Dds     3    4    DDS
.MODEL     DDS    D(IS=7.437E-12 N=1.085 RS=1.914e-3 TRS1=3.315e-2 eg=1.121 CJO=-2.679e-10 M=4.558e-1 VJ=2.321e-1)
Dbody   3    D    DBODY
.MODEL   DBODY    D(IS=7.437E-12 N=1.085 RS=8.914e-3 eg=1.121 BV=44 IBV=250e-6 TBV1=9.732e-4 TT=25n)
Ra      4    2    1e-4 
Rs      3    5    1e-4
Ls      5    S    0.001n 
M2     1t    8    6    6   INTER
E2      8    6    4    1t   2
.MODEL   INTER    NMOS(VTO=0  KP=10   LEVEL=1)
Cgdmax  7    4    4.194e-10 ic=0
Rcgd    7    4    10meg
Dgd     6    4    DGD
Rdgd    4    6    10meg
.MODEL     DGD    D(M=0.4520  CJO=4.588e-10   VJ=0.4631)
M3      7    9    1t    1t   INTER
E3      9    1t    4    1t   -2
.ENDS 
*$
